Installed Oh-My-Zsh, slight polybar change (brightness)

.oh-my-zsh/plugins/ssh-agent/README.md

@@ -0,0 +1,38 @@
+# ssh-agent plugin
+
+This plugin starts automatically `ssh-agent` to set up and load whichever
+credentials you want for ssh connections.
+
+To enable it, add `ssh-agent` to your plugins:
+
+```zsh
+plugins=(... ssh-agent)
+```
+
+## Instructions
+
+To enable **agent forwarding support** add the following to your zshrc file:
+
+```zsh
+zstyle :omz:plugins:ssh-agent agent-forwarding on
+```
+
+To **load multiple identities** use the `identities` style, For example:
+
+```zsh
+zstyle :omz:plugins:ssh-agent identities id_rsa id_rsa2 id_github
+```
+
+To **set the maximum lifetime of the identities**, use the `lifetime` style.
+The lifetime may be specified in seconds or as described in sshd_config(5)
+(see _TIME FORMATS_). If left unspecified, the default lifetime is forever.
+
+```zsh
+zstyle :omz:plugins:ssh-agent lifetime 4h
+```
+
+## Credits
+
+Based on code from Joseph M. Reagle: http://www.cygwin.com/ml/cygwin/2001-06/msg00537.html
+
+Agent-forwarding support based on ideas from Florent Thoumie and Jonas Pfenniger

.oh-my-zsh/plugins/ssh-agent/ssh-agent.plugin.zsh

@@ -0,0 +1,42 @@
+typeset _agent_forwarding _ssh_env_cache
+
+function _start_agent() {
+	local lifetime
+	local -a identities
+
+	# start ssh-agent and setup environment
+	zstyle -s :omz:plugins:ssh-agent lifetime lifetime
+
+	ssh-agent -s ${lifetime:+-t} ${lifetime} | sed 's/^echo/#echo/' >! $_ssh_env_cache
+	chmod 600 $_ssh_env_cache
+	. $_ssh_env_cache > /dev/null
+
+	# load identies
+	zstyle -a :omz:plugins:ssh-agent identities identities
+
+	echo starting ssh-agent...
+	ssh-add $HOME/.ssh/${^identities}
+}
+
+# Get the filename to store/lookup the environment from
+_ssh_env_cache="$HOME/.ssh/environment-$SHORT_HOST"
+
+# test if agent-forwarding is enabled
+zstyle -b :omz:plugins:ssh-agent agent-forwarding _agent_forwarding
+
+if [[ $_agent_forwarding == "yes" && -n "$SSH_AUTH_SOCK" ]]; then
+	# Add a nifty symlink for screen/tmux if agent forwarding
+	[[ -L $SSH_AUTH_SOCK ]] || ln -sf "$SSH_AUTH_SOCK" /tmp/ssh-agent-$USER-screen
+elif [[ -f "$_ssh_env_cache" ]]; then
+	# Source SSH settings, if applicable
+	. $_ssh_env_cache > /dev/null
+	ps x | grep ssh-agent | grep -q $SSH_AGENT_PID || {
+		_start_agent
+	}
+else
+	_start_agent
+fi
+
+# tidy up after ourselves
+unset _agent_forwarding _ssh_env_cache
+unfunction _start_agent